[Tinyos-2-commits] CVS: tinyos-2.x/apps/tests/cc2420/LplUnicastPeriodicDelivery Makefile, NONE, 1.1 README.txt, NONE, 1.1 TestPeriodic.h, NONE, 1.1 TestPeriodicC.nc, NONE, 1.1 TestPeriodicP.nc, NONE, 1.1

[dmm]

Update of /cvsroot/tinyos/tinyos-2.x/apps/tests/cc2420/LplUnicastPeriodicDelivery
In directory sc8-pr-cvs10.sourceforge.net:/tmp/cvs-serv20118/LplUnicastPeriodicDelivery

Added Files:
	Makefile README.txt TestPeriodic.h TestPeriodicC.nc 
	TestPeriodicP.nc 
Log Message:
Supporting test suite for the newest CC2420 stack.  Includes a low power version of RadioCountToLeds, TxThroughput analysis, TestAck, Unicast and Broadcast deliveries, RssiToSerial channel analyzer, and the PacketLink test app.

--- NEW FILE: Makefile ---
COMPONENT=TestPeriodicC
CFLAGS += -DACK_LOW_POWER_LISTENING
#CFLAGS += -DNOACK_LOW_POWER_LISTENING

include $(MAKERULES)


 

--- NEW FILE: README.txt ---
Tx != 0
Rx == 0

This app sends a message from Tx to 0 and waits 1000 ms between each delivery
so the Rx mote's radio shuts back off and has to redetect to receive the next
message.



EXPECTATIONS
Transmitter #1
  * Transmitting for 1000 ms, and then pause for 1000 ms.  
  * Will cut transmission short if using Ack LPL and the receiver gets the msg
  * Led0 indicates transmission
  * Transmitter receive check interval once every 1000 ms
  
Receiver #0
  * Receive check interval once every 1000 ms
  * Led1 indicates final reception

Led2 is left up to DutyCycleP to toggle when the radio is on.


--- NEW FILE: TestPeriodic.h ---

#ifndef TESTPERIODIC_H
#define TESTPERIODIC_H

typedef nx_struct TestPeriodicMsg {
  nx_uint8_t count;
} TestPeriodicMsg;

enum {
  AM_TESTPERIODICMSG = 0x5,
};

#endif


--- NEW FILE: TestPeriodicC.nc ---
/*
 * Copyright (c) 2005-2006 Rincon Research Corporation
 * All rights reserved.
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions
 * are met:
 * - Redistributions of source code must retain the above copyright
 *   notice, this list of conditions and the following disclaimer.
 * - Redistributions in binary form must reproduce the above copyright
 *   notice, this list of conditions and the following disclaimer in the
 *   documentation and/or other materials provided with the
 *   distribution.
 * - Neither the name of the Rincon Research Corporation nor the names of
 *   its contributors may be used to endorse or promote products derived
 *   from this software without specific prior written permission.
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
 * FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE
 * ARCHED ROCK OR ITS CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
 * (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
 * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
 * STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
 * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
 * OF THE POSSIBILITY OF SUCH DAMAGE
 */

/**
 * @author David Moss
 */
 
#include "TestPeriodic.h"

configuration TestPeriodicC {
}

implementation {

#if defined(PLATFORM_MICA2) || defined(PLATFORM_MICA2DOT)
  components CC1000ActiveMessageC as Lpl;
#elif defined(PLATFORM_MICAZ) || defined(PLATFORM_TELOSB)
  components CC2420ActiveMessageC as Lpl;
#else
#error "LPL testing not supported on this platform"
#endif

  components TestPeriodicP,
      MainC,
      ActiveMessageC,
      new TimerMilliC(),
      new AMSenderC(AM_TESTPERIODICMSG),
      new AMReceiverC(AM_TESTPERIODICMSG),
      LedsC;
      
  TestPeriodicP.Boot -> MainC;
  TestPeriodicP.SplitControl -> ActiveMessageC;
  TestPeriodicP.LowPowerListening -> Lpl;
  TestPeriodicP.AMPacket -> ActiveMessageC;
  TestPeriodicP.AMSend -> AMSenderC;
  TestPeriodicP.Receive -> AMReceiverC;
  TestPeriodicP.Packet -> ActiveMessageC;
  TestPeriodicP.Timer -> TimerMilliC;
  TestPeriodicP.Leds -> LedsC;

}


--- NEW FILE: TestPeriodicP.nc ---
/*
 * Copyright (c) 2005-2006 Rincon Research Corporation
 * All rights reserved.
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions
 * are met:
 * - Redistributions of source code must retain the above copyright
 *   notice, this list of conditions and the following disclaimer.
 * - Redistributions in binary form must reproduce the above copyright
 *   notice, this list of conditions and the following disclaimer in the
 *   documentation and/or other materials provided with the
 *   distribution.
 * - Neither the name of the Rincon Research Corporation nor the names of
 *   its contributors may be used to endorse or promote products derived
 *   from this software without specific prior written permission.
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
 * FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE
 * ARCHED ROCK OR ITS CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
 * (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
 * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
 * STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
 * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
 * OF THE POSSIBILITY OF SUCH DAMAGE
 */

/**
 * @author David Moss
 * Rx == 0
 * Tx != 0
 */

#include "TestPeriodic.h"

module TestPeriodicP {
  uses {
    interface Boot;
    interface SplitControl;
    interface LowPowerListening;
    interface AMSend;
    interface Receive;
    interface AMPacket;
    interface Packet;
    interface Leds;
    interface Timer<TMilli>;
  }
}

implementation {
 
  uint8_t count;
  message_t fullMsg;
  bool transmitter;
  
  /**************** Prototypes ****************/
  task void send();
  
  /**************** Boot Events ****************/
  event void Boot.booted() {
    transmitter = (call AMPacket.address() != 0);
    count = 0;
    
    call LowPowerListening.setLocalSleepInterval(1000);
    call SplitControl.start();
  }
  
  event void SplitControl.startDone(error_t error) {
    if(transmitter) {
      post send();
    }
  }
  
  event void SplitControl.stopDone(error_t error) {
  }
  
  
  /**************** Send Receive Events *****************/
  event void AMSend.sendDone(message_t *msg, error_t error) {
    if(transmitter) {
      count++; 
      call Timer.startOneShot(1000);
      call Leds.led0Off();
    }
  }
  
  event message_t *Receive.receive(message_t *msg, void *payload, uint8_t len) {
    if(!transmitter) {
      call Leds.led1Toggle();
    }
    return msg;
  }
  
  /**************** Timer Events ****************/
  event void Timer.fired() {
    if(transmitter) {
      post send();
    }
  }
  
  /**************** Tasks ****************/
  task void send() {
    TestPeriodicMsg *periodicMsg = (TestPeriodicMsg *) call Packet.getPayload(&fullMsg, NULL);
    periodicMsg->count = count;
    call LowPowerListening.setRxSleepInterval(&fullMsg, 1000);
    if(call AMSend.send(0, &fullMsg, sizeof(TestPeriodicMsg)) != SUCCESS) {
      post send();
    } else {
      call Leds.led0On();
    }
  }
}