[Tinyos-2-commits] CVS: tinyos-2.x/apps/tests/TestLpl Makefile, NONE, 1.1 README.txt, NONE, 1.1 TestLplAppC.nc, NONE, 1.1 TestLplC.nc, NONE, 1.1

Wed Jul 2 10:42:44 PDT 2008

Update of /cvsroot/tinyos/tinyos-2.x/apps/tests/TestLpl
In directory sc8-pr-cvs10.sourceforge.net:/tmp/cvs-serv22967/TestLpl

Added Files:
	Makefile README.txt TestLplAppC.nc TestLplC.nc 
Log Message:
renames

--- NEW FILE: Makefile ---
COMPONENT=TestLplAppC

include $(MAKERULES)

--- NEW FILE: README.txt ---
README for TestLPL
Author/Contact: tinyos-help at millennium.berkeley.edu

Description:

A simple low-power-listening test app, which cycles through different
low-power-listening settings every ~32s, repeating every ~256s. 

This application currently runs on motes using the CC1000, CC2420 and
RF230 radios. To compile for motes with CC2420 or RF230 radios, you
must do:
  env CFLAGS="-DLOW_POWER_LISTENING" make <platform>

This application blinks LED 0 every time it sends a message, and toggles
LED 1 every time it receives a message. If this application is
working correctly (see caveat about timing below), you should see 
both nodes toggling LED 1.

Its low-power-listening settings are as follows (repeating every 256s):

0-32s:     receive: fully on
           send: every second, to fully on listener

32-64s:    receive: fully on
	   send: every second, to low-power-listeners with 100ms interval

64-96s:    receive: low-power-listening with 250ms interval
	   send: every second, to low-power-listeners with 250ms interval

96-128s:   receive: low-power-listening with 250ms interval
	   send: every second, to fully on listener

128-160s:  receive: low-power-listening with 10ms interval
	   send: every second, to low-power-listeners with 10ms interval

160-192s:  receive: low-power-listening with 2000ms interval
	   send: every 7 seconds, to low-power-listeners with 2000ms interval

192-224s:  receive: low-power-listening with 1% duty cycle
	   send: every 7 seconds, to low-power-listeners with 1% duty cycle

224-256s:  receive: low-power-listening with 0.1% duty cycle
	   send: every 7 seconds, to low-power-listeners with 0.1% duty cycle

Whether two motes running TestLPL can receive each others messages depends
on their current send and receive low-power-listening settings. If you reset
two such motes at the same time, they will be able to receive each other's
messages in the following intervals: 0-96s and 128-256s.

Tools:

None.

Known bugs/limitations:

None.

--- NEW FILE: TestLplAppC.nc ---
// $Id: TestLplAppC.nc,v 1.1 2008/07/02 17:42:42 idgay Exp $

/*									tab:4
 * "Copyright (c) 2000-2005 The Regents of the University  of California.  
 * All rights reserved.
 *
 * Permission to use, copy, modify, and distribute this software and its
 * documentation for any purpose, without fee, and without written agreement is
 * hereby granted, provided that the above copyright notice, the following
 * two paragraphs and the author appear in all copies of this software.
 * 
 * IN NO EVENT SHALL THE UNIVERSITY OF CALIFORNIA BE LIABLE TO ANY PARTY FOR
 * DIRECT, INDIRECT, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL DAMAGES ARISING OUT
 * OF THE USE OF THIS SOFTWARE AND ITS DOCUMENTATION, EVEN IF THE UNIVERSITY OF
 * CALIFORNIA HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 * 
 * THE UNIVERSITY OF CALIFORNIA SPECIFICALLY DISCLAIMS ANY WARRANTIES,
 * INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
 * AND FITNESS FOR A PARTICULAR PURPOSE.  THE SOFTWARE PROVIDED HEREUNDER IS
 * ON AN "AS IS" BASIS, AND THE UNIVERSITY OF CALIFORNIA HAS NO OBLIGATION TO
 * PROVIDE MAINTENANCE, SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS."
 *
 * Copyright (c) 2002-2005 Intel Corporation
 * All rights reserved.
 *
 * This file is distributed under the terms in the attached INTEL-LICENSE     
 * file. If you do not find these files, copies can be found by writing to
 * Intel Research Berkeley, 2150 Shattuck Avenue, Suite 1300, Berkeley, CA, 
 * 94704.  Attention:  Intel License Inquiry.
 */

/**
 * Simple test code for low-power-listening. Sends a sequence of packets,
 * changing the low-power-listening settings every ~32s. See README.txt
 * for more details.
 *
 *  @author Philip Levis, David Gay
 *  @date   Oct 27 2006
 */

configuration TestLplAppC {}
implementation {
  components MainC, TestLplC as App, LedsC;
  components ActiveMessageC;
  components new TimerMilliC();
#if defined(PLATFORM_MICA2) || defined(PLATFORM_MICA2DOT)
  components CC1000CsmaRadioC as LplRadio;
#elif defined(PLATFORM_MICAZ) || defined(PLATFORM_TELOSB) || defined(PLATFORM_SHIMMER) || defined(PLATFORM_INTELMOTE2)
  components CC2420ActiveMessageC as LplRadio;
#elif defined(PLATFORM_IRIS)
  components RF230ActiveMessageC as LplRadio;
#else
#error "LPL testing not supported on this platform"
#endif

  App.Boot -> MainC.Boot;

  App.Receive -> ActiveMessageC.Receive[240];
  App.AMSend -> ActiveMessageC.AMSend[240];
  App.SplitControl -> ActiveMessageC;
  App.Leds -> LedsC;
  App.MilliTimer -> TimerMilliC;
  App.LowPowerListening -> LplRadio;
}

--- NEW FILE: TestLplC.nc ---
// $Id: TestLplC.nc,v 1.1 2008/07/02 17:42:42 idgay Exp $

/*									tab:4
 * "Copyright (c) 2000-2005 The Regents of the University  of California.  
 * All rights reserved.
 *
 * Permission to use, copy, modify, and distribute this software and its
 * documentation for any purpose, without fee, and without written agreement is
 * hereby granted, provided that the above copyright notice, the following
 * two paragraphs and the author appear in all copies of this software.
 * 
 * IN NO EVENT SHALL THE UNIVERSITY OF CALIFORNIA BE LIABLE TO ANY PARTY FOR
 * DIRECT, INDIRECT, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL DAMAGES ARISING OUT
 * OF THE USE OF THIS SOFTWARE AND ITS DOCUMENTATION, EVEN IF THE UNIVERSITY OF
 * CALIFORNIA HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 * 
 * THE UNIVERSITY OF CALIFORNIA SPECIFICALLY DISCLAIMS ANY WARRANTIES,
 * INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
 * AND FITNESS FOR A PARTICULAR PURPOSE.  THE SOFTWARE PROVIDED HEREUNDER IS
 * ON AN "AS IS" BASIS, AND THE UNIVERSITY OF CALIFORNIA HAS NO OBLIGATION TO
 * PROVIDE MAINTENANCE, SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS."
 *
 * Copyright (c) 2002-2003 Intel Corporation
 * All rights reserved.
 *
 * This file is distributed under the terms in the attached INTEL-LICENSE     
 * file. If you do not find these files, copies can be found by writing to
 * Intel Research Berkeley, 2150 Shattuck Avenue, Suite 1300, Berkeley, CA, 
 * 94704.  Attention:  Intel License Inquiry.
 */

#include "Timer.h"

/**
 * Simple test code for low-power-listening. Sends a sequence of packets,
 * changing the low-power-listening settings every ~32s. See README.txt
 * for more details.
 *
 *  @author Philip Levis, David Gay
 *  @date   Oct 27 2006
 */

module TestLplC {
  uses {
    interface Leds;
    interface Boot;
    interface Receive;
    interface AMSend;
    interface Timer<TMilli> as MilliTimer;
    interface SplitControl;
    interface LowPowerListening;
  }
}
implementation 
{
  message_t packet;
  bool locked;
  uint8_t counter = 0, sendSkip;
  int16_t sendInterval;

  event void Boot.booted() {
    call SplitControl.start();
  }

  void nextLplState()
  {
    switch (counter >> 5) {
    case 0:
      sendSkip = 0;
      sendInterval = 0;
      call LowPowerListening.setLocalSleepInterval(0);
      break;
    case 1:
      sendInterval = 100; /* Send to sleepy listener */
      break;
    case 2:
      sendInterval = -1; /* Send to listener like us */
      call LowPowerListening.setLocalSleepInterval(250);
      break;
    case 3:
      sendInterval = 0; /* Send to awake listener */
      break;
    case 4:
      sendInterval = -1; /* Send to listener like us */
      call LowPowerListening.setLocalSleepInterval(10);
      break;
    case 5:
      sendSkip = 7; /* Send every 7s */
      call LowPowerListening.setLocalSleepInterval(2000);
      break;
    case 6:
      call LowPowerListening.setLocalDutyCycle(100);
      break;
    case 7:
      call LowPowerListening.setLocalDutyCycle(10);
      break;
    }
  }

  event void MilliTimer.fired()
  {
    counter++;
    if (!(counter & 31))
      nextLplState();

    if (!locked && ((counter & sendSkip) == sendSkip))
      {
	if (sendInterval >= 0)
	  call LowPowerListening.setRxSleepInterval(&packet, sendInterval);
	if (call AMSend.send(AM_BROADCAST_ADDR, &packet, 0) == SUCCESS)
	  {
	    call Leds.led0On();
	    locked = TRUE;
	  }
      }
  }

  event message_t* Receive.receive(message_t* bufPtr, 
				   void* payload, uint8_t len)
  {
    call Leds.led1Toggle();
    return bufPtr;
  }

  event void AMSend.sendDone(message_t* bufPtr, error_t error)
  {
    if (&packet == bufPtr)
      {
	locked = FALSE;
	call Leds.led0Off();
      }
  }

  event void SplitControl.startDone(error_t err)
  {
    call MilliTimer.startPeriodic(1000);
  }

  event void SplitControl.stopDone(error_t err) { }
}