[Tinyos-commits] CVS: tinyos-1.x/tos/lib/Deluge/TOSBoot Exec.nc,
NONE, 1.1 ExtFlash.nc, NONE, 1.1 Hardware.nc, NONE,
1.1 Leds.nc, NONE, 1.1 LedsC.nc, NONE, 1.1 Makefile, 1.13,
1.14 ProgFlash.nc, NONE, 1.1 TOSBoot.nc, NONE, 1.1 TOSBootM.nc,
NONE, 1.1 Voltage.nc, NONE, 1.1 crc.h, NONE, 1.1
Jonathan Hui
jwhui at users.sourceforge.net
Fri Jul 22 10:40:11 PDT 2005
- Previous message: [Tinyos-commits] CVS: tinyos-1.x/tos/lib/Deluge/TOSBoot/at45db
ExtFlashC.nc, NONE, 1.1
- Next message: [Tinyos-commits] CVS: tinyos-1.x/tos/lib/Deluge/TOSBoot/avr
HardwareC.nc, NONE, 1.1 InternalFlashC.nc, NONE,
1.1 ProgFlashM.nc, NONE, 1.1 boot.h, NONE, 1.1
- Messages sorted by:
[ date ]
[ thread ]
[ subject ]
[ author ]
Update of /cvsroot/tinyos/tinyos-1.x/tos/lib/Deluge/TOSBoot
In directory sc8-pr-cvs1.sourceforge.net:/tmp/cvs-serv22969/TOSBoot
Added Files:
Exec.nc ExtFlash.nc Hardware.nc Leds.nc LedsC.nc Makefile
ProgFlash.nc TOSBoot.nc TOSBootM.nc Voltage.nc crc.h
Log Message:
- Initial import of Deluge 2.0.
--- NEW FILE: Exec.nc ---
interface Exec {
command void exec();
}
--- NEW FILE: ExtFlash.nc ---
// $Id: ExtFlash.nc,v 1.1 2005/07/22 17:40:09 jwhui Exp $
/* tab:2
*
*
* "Copyright (c) 2000-2005 The Regents of the University of California.
* All rights reserved.
*
* Permission to use, copy, modify, and distribute this software and its
* documentation for any purpose, without fee, and without written agreement is
* hereby granted, provided that the above copyright notice, the following
* two paragraphs and the author appear in all copies of this software.
*
* IN NO EVENT SHALL THE UNIVERSITY OF CALIFORNIA BE LIABLE TO ANY PARTY FOR
* DIRECT, INDIRECT, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL DAMAGES ARISING OUT
* OF THE USE OF THIS SOFTWARE AND ITS DOCUMENTATION, EVEN IF THE UNIVERSITY OF
* CALIFORNIA HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*
* THE UNIVERSITY OF CALIFORNIA SPECIFICALLY DISCLAIMS ANY WARRANTIES,
* INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
* AND FITNESS FOR A PARTICULAR PURPOSE. THE SOFTWARE PROVIDED HEREUNDER IS
* ON AN "AS IS" BASIS, AND THE UNIVERSITY OF CALIFORNIA HAS NO OBLIGATION TO
* PROVIDE MAINTENANCE, SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS."
*
*/
/**
* @author Jonathan Hui <jwhui at cs.berkeley.edu>
*/
interface ExtFlash {
command void startRead(uint32_t addr);
command uint8_t readByte();
command void stopRead();
}
--- NEW FILE: Hardware.nc ---
// $Id: Hardware.nc,v 1.1 2005/07/22 17:40:09 jwhui Exp $
/* tab:2
*
*
* "Copyright (c) 2000-2005 The Regents of the University of California.
* All rights reserved.
*
* Permission to use, copy, modify, and distribute this software and its
* documentation for any purpose, without fee, and without written agreement is
* hereby granted, provided that the above copyright notice, the following
* two paragraphs and the author appear in all copies of this software.
*
* IN NO EVENT SHALL THE UNIVERSITY OF CALIFORNIA BE LIABLE TO ANY PARTY FOR
* DIRECT, INDIRECT, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL DAMAGES ARISING OUT
* OF THE USE OF THIS SOFTWARE AND ITS DOCUMENTATION, EVEN IF THE UNIVERSITY OF
* CALIFORNIA HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*
* THE UNIVERSITY OF CALIFORNIA SPECIFICALLY DISCLAIMS ANY WARRANTIES,
* INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
* AND FITNESS FOR A PARTICULAR PURPOSE. THE SOFTWARE PROVIDED HEREUNDER IS
* ON AN "AS IS" BASIS, AND THE UNIVERSITY OF CALIFORNIA HAS NO OBLIGATION TO
* PROVIDE MAINTENANCE, SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS."
*
*/
/**
* @author Jonathan Hui <jwhui at cs.berkeley.edu>
*/
interface Hardware {
command void init();
command void reboot();
}
--- NEW FILE: Leds.nc ---
// $Id: Leds.nc,v 1.1 2005/07/22 17:40:09 jwhui Exp $
/* tab:2
*
*
* "Copyright (c) 2000-2004 The Regents of the University of California.
* All rights reserved.
*
* Permission to use, copy, modify, and distribute this software and its
* documentation for any purpose, without fee, and without written agreement is
* hereby granted, provided that the above copyright notice, the following
* two paragraphs and the author appear in all copies of this software.
*
* IN NO EVENT SHALL THE UNIVERSITY OF CALIFORNIA BE LIABLE TO ANY PARTY FOR
* DIRECT, INDIRECT, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL DAMAGES ARISING OUT
* OF THE USE OF THIS SOFTWARE AND ITS DOCUMENTATION, EVEN IF THE UNIVERSITY OF
* CALIFORNIA HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*
* THE UNIVERSITY OF CALIFORNIA SPECIFICALLY DISCLAIMS ANY WARRANTIES,
* INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
* AND FITNESS FOR A PARTICULAR PURPOSE. THE SOFTWARE PROVIDED HEREUNDER IS
* ON AN "AS IS" BASIS, AND THE UNIVERSITY OF CALIFORNIA HAS NO OBLIGATION TO
* PROVIDE MAINTENANCE, SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS."
*
*/
/**
* @author Jonathan Hui <jwhui at cs.berkeley.edu>
*/
interface Leds {
command void set(uint8_t ledsOn);
command void flash(uint8_t a);
command void glow(uint8_t a, uint8_t b);
}
--- NEW FILE: LedsC.nc ---
// $Id: LedsC.nc,v 1.1 2005/07/22 17:40:09 jwhui Exp $
/* tab:2
*
*
* "Copyright (c) 2000-2004 The Regents of the University of California.
* All rights reserved.
*
* Permission to use, copy, modify, and distribute this software and its
* documentation for any purpose, without fee, and without written agreement is
* hereby granted, provided that the above copyright notice, the following
* two paragraphs and the author appear in all copies of this software.
*
* IN NO EVENT SHALL THE UNIVERSITY OF CALIFORNIA BE LIABLE TO ANY PARTY FOR
* DIRECT, INDIRECT, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL DAMAGES ARISING OUT
* OF THE USE OF THIS SOFTWARE AND ITS DOCUMENTATION, EVEN IF THE UNIVERSITY OF
* CALIFORNIA HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*
* THE UNIVERSITY OF CALIFORNIA SPECIFICALLY DISCLAIMS ANY WARRANTIES,
* INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
* AND FITNESS FOR A PARTICULAR PURPOSE. THE SOFTWARE PROVIDED HEREUNDER IS
* ON AN "AS IS" BASIS, AND THE UNIVERSITY OF CALIFORNIA HAS NO OBLIGATION TO
* PROVIDE MAINTENANCE, SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS."
*
*/
/**
* @author Jonathan Hui <jwhui at cs.berkeley.edu>
*/
module LedsC {
provides interface Leds;
}
implementation {
enum {
RED_BIT = 1,
GREEN_BIT = 2,
YELLOW_BIT = 4
};
command void Leds.set(uint8_t ledsOn) {
if (ledsOn & GREEN_BIT)
TOSH_CLR_GREEN_LED_PIN();
else
TOSH_SET_GREEN_LED_PIN();
if (ledsOn & YELLOW_BIT )
TOSH_CLR_YELLOW_LED_PIN();
else
TOSH_SET_YELLOW_LED_PIN();
if (ledsOn & RED_BIT)
TOSH_CLR_RED_LED_PIN();
else
TOSH_SET_RED_LED_PIN();
}
command void Leds.flash(uint8_t a) {
uint8_t i, j;
for ( i = 3; i; i-- ) {
call Leds.set(a);
for ( j = 4; j; j-- )
wait(0xffff);
call Leds.set(0);
for ( j = 4; j; j-- )
wait(0xffff);
}
}
command void Leds.glow(uint8_t a, uint8_t b) {
int i;
for (i = 1536; i > 0; i -= 4) {
call Leds.set(a);
wait(i);
call Leds.set(b);
wait(1536-i);
}
}
}
--- NEW FILE: ProgFlash.nc ---
// $Id: ProgFlash.nc,v 1.1 2005/07/22 17:40:09 jwhui Exp $
/* tab:2
*
*
* "Copyright (c) 2000-2005 The Regents of the University of California.
* All rights reserved.
*
* Permission to use, copy, modify, and distribute this software and its
* documentation for any purpose, without fee, and without written agreement is
* hereby granted, provided that the above copyright notice, the following
* two paragraphs and the author appear in all copies of this software.
*
* IN NO EVENT SHALL THE UNIVERSITY OF CALIFORNIA BE LIABLE TO ANY PARTY FOR
* DIRECT, INDIRECT, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL DAMAGES ARISING OUT
* OF THE USE OF THIS SOFTWARE AND ITS DOCUMENTATION, EVEN IF THE UNIVERSITY OF
* CALIFORNIA HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*
* THE UNIVERSITY OF CALIFORNIA SPECIFICALLY DISCLAIMS ANY WARRANTIES,
* INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
* AND FITNESS FOR A PARTICULAR PURPOSE. THE SOFTWARE PROVIDED HEREUNDER IS
* ON AN "AS IS" BASIS, AND THE UNIVERSITY OF CALIFORNIA HAS NO OBLIGATION TO
* PROVIDE MAINTENANCE, SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS."
*
*/
/**
* @author Jonathan Hui <jwhui at cs.berkeley.edu>
*/
interface ProgFlash {
command result_t write(uint32_t addr, uint8_t* buf, uint16_t len);
}
--- NEW FILE: TOSBoot.nc ---
// $Id: TOSBoot.nc,v 1.1 2005/07/22 17:40:09 jwhui Exp $
/* tab:2
*
*
* "Copyright (c) 2000-2005 The Regents of the University of California.
* All rights reserved.
*
* Permission to use, copy, modify, and distribute this software and its
* documentation for any purpose, without fee, and without written agreement is
* hereby granted, provided that the above copyright notice, the following
* two paragraphs and the author appear in all copies of this software.
*
* IN NO EVENT SHALL THE UNIVERSITY OF CALIFORNIA BE LIABLE TO ANY PARTY FOR
* DIRECT, INDIRECT, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL DAMAGES ARISING OUT
* OF THE USE OF THIS SOFTWARE AND ITS DOCUMENTATION, EVEN IF THE UNIVERSITY OF
* CALIFORNIA HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*
* THE UNIVERSITY OF CALIFORNIA SPECIFICALLY DISCLAIMS ANY WARRANTIES,
* INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
* AND FITNESS FOR A PARTICULAR PURPOSE. THE SOFTWARE PROVIDED HEREUNDER IS
* ON AN "AS IS" BASIS, AND THE UNIVERSITY OF CALIFORNIA HAS NO OBLIGATION TO
* PROVIDE MAINTENANCE, SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS."
*
*/
/**
* @author Jonathan Hui <jwhui at cs.berkeley.edu>
*/
includes Deluge;
includes TOSBoot;
configuration TOSBoot {
}
implementation {
components
TOSBootM,
ExecC,
ExtFlashC,
HardwareC,
InternalFlashC as IntFlash,
LedsC,
PluginC,
ProgFlashM as ProgFlash,
VoltageC;
TOSBootM.SubControl -> ExtFlashC.StdControl;
TOSBootM.SubControl -> PluginC;
TOSBootM.Exec -> ExecC;
TOSBootM.ExtFlash -> ExtFlashC;
TOSBootM.Hardware -> HardwareC;
TOSBootM.IntFlash -> IntFlash;
TOSBootM.Leds -> LedsC;
TOSBootM.ProgFlash -> ProgFlash;
TOSBootM.Voltage -> VoltageC;
}
--- NEW FILE: TOSBootM.nc ---
// $Id: TOSBootM.nc,v 1.1 2005/07/22 17:40:09 jwhui Exp $
/* tab:2
* "Copyright (c) 2000-2005 The Regents of the University of California.
* All rights reserved.
*
* Permission to use, copy, modify, and distribute this software and its
* documentation for any purpose, without fee, and without written agreement is
* hereby granted, provided that the above copyright notice, the following
* two paragraphs and the author appear in all copies of this software.
*
* IN NO EVENT SHALL THE UNIVERSITY OF CALIFORNIA BE LIABLE TO ANY PARTY FOR
* DIRECT, INDIRECT, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL DAMAGES ARISING OUT
* OF THE USE OF THIS SOFTWARE AND ITS DOCUMENTATION, EVEN IF THE UNIVERSITY OF
* CALIFORNIA HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*
* THE UNIVERSITY OF CALIFORNIA SPECIFICALLY DISCLAIMS ANY WARRANTIES,
* INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
* AND FITNESS FOR A PARTICULAR PURPOSE. THE SOFTWARE PROVIDED HEREUNDER IS
* ON AN "AS IS" BASIS, AND THE UNIVERSITY OF CALIFORNIA HAS NO OBLIGATION TO
* PROVIDE MAINTENANCE, SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS."
*/
/*
* @author: Jonathan Hui <jwhui at cs.berkeley.edu>
*/
includes crc;
includes hardware;
module TOSBootM {
uses {
interface Exec;
interface ExtFlash;
interface Hardware;
interface InternalFlash as IntFlash;
interface Leds;
interface ProgFlash;
interface StdControl as SubControl;
interface Voltage;
}
}
implementation {
enum {
LEDS_LOWBATT = 1,
LEDS_GESTURE = 7,
};
enum {
R_SUCCESS,
R_INVALID_IMAGE_ERROR,
R_PROGRAMMING_ERROR,
};
void startupLeds() {
uint8_t output = 0x7;
uint8_t i;
for (i = 3; i; i--, output >>= 1 )
call Leds.glow(output, output >> 1);
}
uint32_t extFlashRead32() {
uint32_t result = 0;
uint8_t i;
for ( i = 0; i < 4; i++ )
result |= ((uint32_t)call ExtFlash.readByte() & 0xff) << (i*8);
return result;
}
bool verifyImage(uint32_t startAddr) {
uint16_t crcTarget = 0, crcTmp = 0;
uint16_t addr, len;
pgnum_t numPgs;
uint8_t i;
// read size of image
call ExtFlash.startRead(startAddr + offsetof(DelugeImgDesc,numPgs));
numPgs = call ExtFlash.readByte();
call ExtFlash.stopRead();
if (numPgs == 0 || numPgs == 0xff)
return FALSE;
startAddr += DELUGE_METADATA_SIZE;
addr = DELUGE_CRC_BLOCK_SIZE;
len = DELUGE_BYTES_PER_PAGE-DELUGE_CRC_BLOCK_SIZE;
for ( i = 0; i < numPgs && crcTarget == crcTmp; i++ ) {
// read crc
call ExtFlash.startRead(startAddr + i*sizeof(uint16_t));
crcTarget = (uint16_t)(call ExtFlash.readByte() & 0xff);
crcTarget |= (uint16_t)(call ExtFlash.readByte() & 0xff) << 8;
call ExtFlash.stopRead();
// compute crc
call ExtFlash.startRead(startAddr + addr);
for ( crcTmp = 0; len; len-- )
crcTmp = crcByte(crcTmp, call ExtFlash.readByte());
call ExtFlash.stopRead();
addr = (uint16_t)(i+1)*DELUGE_BYTES_PER_PAGE;
len = DELUGE_BYTES_PER_PAGE;
}
return (i == numPgs);
}
result_t programImage(uint32_t startAddr) {
uint8_t buf[TOSBOOT_INT_PAGE_SIZE];
uint16_t pageAddr, newPageAddr;
uint32_t intAddr;
uint32_t secLength;
if (!verifyImage(startAddr))
return R_INVALID_IMAGE_ERROR;
startAddr += DELUGE_METADATA_SIZE + DELUGE_CRC_BLOCK_SIZE + DELUGE_IDENT_SIZE;
call ExtFlash.startRead(startAddr);
intAddr = extFlashRead32();
secLength = extFlashRead32();
while ( secLength ) {
pageAddr = newPageAddr = intAddr / TOSBOOT_INT_PAGE_SIZE;
// fill in ram buffer for internal program flash sector
do {
// check if secLength is all ones
if ( secLength == 0xffffffff )
return FAIL;
buf[(uint16_t)intAddr % TOSBOOT_INT_PAGE_SIZE] = call ExtFlash.readByte();
intAddr++;
if ( --secLength == 0 ) {
intAddr = extFlashRead32();
secLength = extFlashRead32();
}
newPageAddr = intAddr / TOSBOOT_INT_PAGE_SIZE;
} while ( pageAddr == newPageAddr && secLength );
call Leds.set(pageAddr);
// write out page
if (call ProgFlash.write(pageAddr*TOSBOOT_INT_PAGE_SIZE, buf,
TOSBOOT_INT_PAGE_SIZE) == FAIL)
return R_PROGRAMMING_ERROR;
}
call ExtFlash.stopRead();
return R_SUCCESS;
}
void runApp() {
call SubControl.stop();
call Exec.exec();
}
void startupSequence() {
tosboot_args_t args;
// check voltage and make sure flash can be programmed
// if not, just run the app, can't check for gestures
// if we can't write to the internal flash anyway
if ( !call Voltage.okToProgram() ) {
// give user some time and count down LEDs
call Leds.flash(LEDS_LOWBATT);
startupLeds();
runApp();
}
// get current value of counter
call IntFlash.read((uint8_t*)TOSBOOT_ARGS_ADDR, &args, sizeof(args));
// increment gesture counter, see if it exceeds threshold
if ( ++args.gestureCount >= TOSBOOT_GESTURE_MAX_COUNT - 1 ) {
// gesture has been detected, display receipt of gesture on LEDs
call Leds.flash(LEDS_GESTURE);
// load golden image from flash
// if the golden image is invalid, forget about reprogramming
// if an error happened during reprogramming, reboot and try again
// not much else we can do :-/
if (programImage(TOSBOOT_GOLDEN_IMG_ADDR) == R_PROGRAMMING_ERROR)
call Hardware.reboot();
}
else {
// update gesture counter
call IntFlash.write((uint8_t*)TOSBOOT_ARGS_ADDR, &args, sizeof(args));
if ( !args.noReprogram ) {
// if an error happened during reprogramming, reboot and try again
// after two tries, try programming the golden image
if (programImage(args.imageAddr) == R_PROGRAMMING_ERROR)
call Hardware.reboot();
}
}
// give user some time and count down LEDs
startupLeds();
// reset counter and reprogramming flag
args.gestureCount = 0xff;
args.noReprogram = TRUE;
call IntFlash.write((uint8_t*)TOSBOOT_ARGS_ADDR, &args, sizeof(args));
runApp();
}
int main() __attribute__ ((C, spontaneous)) {
__nesc_disable_interrupt();
TOSH_SET_PIN_DIRECTIONS();
call Hardware.init();
call SubControl.init();
call SubControl.start();
startupSequence();
return 0;
}
}
--- NEW FILE: Voltage.nc ---
// $Id: Voltage.nc,v 1.1 2005/07/22 17:40:09 jwhui Exp $
/* tab:2
*
*
* "Copyright (c) 2000-2004 The Regents of the University of California.
* All rights reserved.
*
* Permission to use, copy, modify, and distribute this software and its
* documentation for any purpose, without fee, and without written agreement is
* hereby granted, provided that the above copyright notice, the following
* two paragraphs and the author appear in all copies of this software.
*
* IN NO EVENT SHALL THE UNIVERSITY OF CALIFORNIA BE LIABLE TO ANY PARTY FOR
* DIRECT, INDIRECT, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL DAMAGES ARISING OUT
* OF THE USE OF THIS SOFTWARE AND ITS DOCUMENTATION, EVEN IF THE UNIVERSITY OF
* CALIFORNIA HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*
* THE UNIVERSITY OF CALIFORNIA SPECIFICALLY DISCLAIMS ANY WARRANTIES,
* INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
* AND FITNESS FOR A PARTICULAR PURPOSE. THE SOFTWARE PROVIDED HEREUNDER IS
* ON AN "AS IS" BASIS, AND THE UNIVERSITY OF CALIFORNIA HAS NO OBLIGATION TO
* PROVIDE MAINTENANCE, SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS."
*
*/
/**
* @author Jonathan Hui <jwhui at cs.berkeley.edu>
*/
interface Voltage {
command bool okToProgram();
}
--- NEW FILE: crc.h ---
// $Id: crc.h,v 1.1 2005/07/22 17:40:09 jwhui Exp $
/* tab:4
* "Copyright (c) 2000-2003 The Regents of the University of California.
* All rights reserved.
*
* Permission to use, copy, modify, and distribute this software and its
* documentation for any purpose, without fee, and without written agreement is
* hereby granted, provided that the above copyright notice, the following
* two paragraphs and the author appear in all copies of this software.
*
* IN NO EVENT SHALL THE UNIVERSITY OF CALIFORNIA BE LIABLE TO ANY PARTY FOR
* DIRECT, INDIRECT, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL DAMAGES ARISING OUT
* OF THE USE OF THIS SOFTWARE AND ITS DOCUMENTATION, EVEN IF THE UNIVERSITY OF
* CALIFORNIA HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*
* THE UNIVERSITY OF CALIFORNIA SPECIFICALLY DISCLAIMS ANY WARRANTIES,
* INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
* AND FITNESS FOR A PARTICULAR PURPOSE. THE SOFTWARE PROVIDED HEREUNDER IS
* ON AN "AS IS" BASIS, AND THE UNIVERSITY OF CALIFORNIA HAS NO OBLIGATION TO
* PROVIDE MAINTENANCE, SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS."
*
* Copyright (c) 2002-2003 Intel Corporation
* All rights reserved.
*
* This file is distributed under the terms in the attached INTEL-LICENSE
* file. If you do not find these files, copies can be found by writing to
* Intel Research Berkeley, 2150 Shattuck Avenue, Suite 1300, Berkeley, CA,
* 94704. Attention: Intel License Inquiry.
*/
/**
* Default CRC function. Note that avrmote has a much more efficient one.
*
* This CRC-16 function produces a 16-bit running CRC that adheres to the
* ITU-T CRC standard.
*
* The ITU-T polynomial is: G_16(x) = x^16 + x^12 + x^5 + 1
*
*/
uint16_t crcByte(uint16_t crc, uint8_t b)
{
uint8_t i;
crc = crc ^ b << 8;
i = 8;
do
if (crc & 0x8000)
crc = crc << 1 ^ 0x1021;
else
crc = crc << 1;
while (--i);
return crc;
}
- Previous message: [Tinyos-commits] CVS: tinyos-1.x/tos/lib/Deluge/TOSBoot/at45db
ExtFlashC.nc, NONE, 1.1
- Next message: [Tinyos-commits] CVS: tinyos-1.x/tos/lib/Deluge/TOSBoot/avr
HardwareC.nc, NONE, 1.1 InternalFlashC.nc, NONE,
1.1 ProgFlashM.nc, NONE, 1.1 boot.h, NONE, 1.1
- Messages sorted by:
[ date ]
[ thread ]
[ subject ]
[ author ]
More information about the Tinyos-commits
mailing list